Fonction SI d’Excel :le guide complet, pas à pas

La fonction SI d’Excel pas à pas : syntaxe, exemples, SI avec ET et OU, SI imbriqués, SI.CONDITIONS, SIERREUR et les erreurs à éviter, en images.

Publié le
Mis à jour le
Thème
Bureautique
Lecture
9 min
Tableur avec la formule =SI(B2>=10;"Admis";"À revoir") et la colonne Résultat

Quand je forme à Excel, la fonction SI est toujours une étape clé. Ce n’est pas la plus difficile, mais c’est elle qui ouvre la porte à toutes les fonctions conditionnelles : une fois qu’on l’a comprise, on peut faire « réfléchir » un tableau. Ce guide part de zéro et va jusqu’aux cas qui posent problème à mes stagiaires.

En bref : =SI(test;valeur_si_vrai;valeur_si_faux). Excel vérifie le test ; s’il est vrai, il affiche la première valeur, sinon la seconde. Exemple : =SI(B2>=18;"Majeur";"Mineur").

Ce que fait la fonction SI

La fonction SI affiche une valeur ou une autre selon qu’une condition est remplie ou non. Elle répond à une question du type : « si cette condition est vraie, fais ceci, sinon fais cela ».

Quelques usages courants en entreprise :

  • afficher « Payé » ou « En attente » selon qu’une date de règlement est remplie ;
  • calculer une prime seulement au-delà d’un chiffre d’affaires ;
  • signaler un stock trop bas ;
  • indiquer « Admis » ou « À revoir » selon une note.

La syntaxe : trois arguments

La fonction SI se compose de trois éléments, séparés par des points-virgules :

  1. Le test logique : une question à laquelle Excel répond par vrai ou faux, par exemple B2>=18 (« la valeur de B2 est-elle supérieure ou égale à 18 ? »).
  2. La valeur si vrai : ce qu’Excel affiche si le test est vérifié.
  3. La valeur si faux : ce qu’Excel affiche sinon.

Pour écrire le test, on utilise les opérateurs de comparaison :

Opérateur Signification Exemple
= égal à A2="Oui"
<> différent de A2<>"Oui"
> supérieur à B2>1000
< inférieur à B2<10
>= supérieur ou égal à B2>=18
<= inférieur ou égal à B2<=0

Deux règles à retenir dès maintenant : le texte s’écrit entre guillemets droits ("Majeur"), les nombres sans guillemets (18). Et dans un Excel en français, les arguments sont séparés par des points-virgules ; dans un Excel en anglais, ce sont des virgules, et la fonction s’appelle IF.

Premier exemple : majeur ou mineur

Exemple d’utilisation de la fonction SI d’Excel : des noms en colonne A, des âges en colonne B

Dans ce tableau, il faut afficher en colonne C « Majeur » ou « Mineur » selon l’âge de la personne, en colonne B. La question à poser à Excel est donc : « la personne a-t-elle 18 ans ou plus ? ». Si oui, on écrit Majeur ; sinon, Mineur.

Il existe deux façons de construire la formule : avec l’assistant, ou en l’écrivant directement. Commencez par l’assistant si vous débutez.

Méthode 1 : avec l’assistant de fonction

L’assistant (ou concepteur de formule) construit la fonction pas à pas et corrige certains oublis, comme les guillemets. Placez-vous d’abord dans la cellule où le résultat doit apparaître, ici C2, puis cliquez sur le petit fx, juste à côté de la barre de formule.

Le bouton fx à côté de la barre de formule d’Excel

Une boîte de dialogue s’ouvre :

La boîte de dialogue du concepteur de formule

Selon que vous êtes sur Mac ou sur Windows, elle ne s’ouvre pas au même endroit, mais elle fonctionne de la même façon. Vous y trouvez :

  • une barre de recherche pour trouver la fonction ;
  • la liste des dernières fonctions utilisées ;
  • la liste complète des fonctions d’Excel.

Double-cliquez sur la fonction SI pour afficher ses arguments :

Les trois arguments de la fonction SI dans l’assistant

On retrouve les trois éléments vus plus haut. Dans le test logique, on écrit la condition : pour être majeur, il faut avoir 18 ans ou plus, donc B2>=18. En valeur si vrai, on écrit Majeur ; en valeur si faux, Mineur.

Les arguments remplis : B2>=18, Majeur, Mineur

Attention à l’ordre des signes : on écrit >= (supérieur, puis égal), jamais l’inverse.

Regardez la barre de formule : Excel y a écrit la formule complète.

=SI(B2>=18;"Majeur";"Mineur")

On y retrouve les trois arguments, et l’assistant a ajouté tout seul les guillemets autour du texte. Cliquez sur Terminer (ou OK).

Le résultat Majeur s’affiche pour Fanny, 22 ans

Fanny a 22 ans : c’est bien « Majeur » qui s’affiche. Il reste à appliquer la formule aux autres lignes avec la poignée de recopie, le petit carré en bas à droite de la cellule : faites-la glisser vers le bas, ou double-cliquez dessus.

La formule recopiée sur toute la colonne grâce à la poignée de recopie

Voir la vidéo : la fonction SI d’Excel

Méthode 2 : écrire la formule dans la cellule

Une fois la logique comprise, il est plus rapide d’écrire la formule directement. Placez-vous dans la cellule, tapez le signe =, puis le début du nom de la fonction.

Excel propose la liste des fonctions qui commencent par SI

Excel propose les fonctions qui correspondent. Double-cliquez sur SI (ou appuyez sur Tab) pour entrer dans la fonction.

L’info-bulle de la fonction SI avec le test logique en surbrillance

Une info-bulle rappelle les trois arguments. Celui qui est en gras est celui que vous êtes en train d’écrire, ici le test logique. Tapez votre test, puis un point-virgule pour passer à l’argument suivant.

Après le point-virgule, l’argument valeur si vrai passe en surbrillance

C’est maintenant « valeur si vrai » qui est en gras. Attention : contrairement à l’assistant, quand vous écrivez vous-même la formule, tout texte doit être entre guillemets. Sinon, Excel affiche l’erreur #NOM?.

La formule presque terminée avec les textes entre guillemets

Il ne reste qu’à fermer la parenthèse. L’info-bulle disparaît : la formule est complète.

La parenthèse fermée, la formule est terminée

Validez avec Entrée, puis recopiez la formule vers le bas avec la poignée de recopie.

Autres tests utiles au quotidien

Tester un texte. =SI(D2="Payé";"OK";"À relancer"). La comparaison ne tient pas compte des majuscules : « payé » et « PAYÉ » donnent le même résultat.

Tester une cellule vide. =SI(D2="";"À compléter";"OK"). Deux guillemets collés signifient « vide ».

Renvoyer un calcul plutôt qu’un texte. Une prime de 5 % au-delà de 1 000 € de ventes : =SI(B2>1000;B2*5%;0). Les valeurs peuvent être des nombres, des calculs ou même d’autres fonctions.

Laisser la cellule vide. Pour ne rien afficher quand la condition n’est pas remplie : =SI(B2>1000;B2*5%;"").

Plusieurs conditions : SI avec ET, SI avec OU

Souvent, une seule condition ne suffit pas.

ET : toutes les conditions doivent être vraies. Une prime si les ventes dépassent 1 000 € et si le client est en Occitanie :

=SI(ET(B2>1000;C2="Occitanie");"Prime";"")

OU : une seule condition suffit. Une livraison gratuite si la commande dépasse 100 € ou si le client est abonné :

=SI(OU(B2>100;C2="Abonné");"Gratuite";"Payante")

NON : inverser une condition. =SI(NON(C2="Abonné");"Proposer l'abonnement";"").

On peut mettre plusieurs conditions dans ET ou dans OU, toujours séparées par des points-virgules : ET(B2>1000;C2="Occitanie";D2<>"").

La même condition, sans le SI, sert aussi à colorer une ligne : c’est la mise en forme conditionnelle, qui fait par exemple ressortir en rouge les factures en retard.

Plus de deux résultats : SI imbriqués et SI.CONDITIONS

La fonction SI ne propose que deux résultats. Pour en avoir davantage, la méthode classique consiste à imbriquer des SI : on place un nouveau SI à la place de la « valeur si faux ». Exemple avec une appréciation selon une note sur 20 :

=SI(B2>=16;"Très bien";SI(B2>=12;"Bien";SI(B2>=10;"Passable";"Insuffisant")))

Excel lit les conditions dans l’ordre et s’arrête à la première vraie. L’ordre compte : si vous testez d’abord B2>=10, un 17 sera classé « Passable ». Et chaque SI ouvert doit être refermé : il faut autant de parenthèses fermantes à la fin que de SI.

Depuis Excel 2019 et dans Microsoft 365, la fonction SI.CONDITIONS fait la même chose, en bien plus lisible. On y écrit les paires « condition ; résultat » à la suite :

=SI.CONDITIONS(B2>=16;"Très bien";B2>=12;"Bien";B2>=10;"Passable";VRAI;"Insuffisant")

Le dernier couple VRAI;"Insuffisant" sert de « sinon » : sans lui, Excel affiche #N/A quand aucune condition n’est remplie. Si vous avez Excel 2019 ou plus récent, préférez SI.CONDITIONS aux SI imbriqués. Pour un fichier partagé avec des collègues sur Excel 2016 ou plus ancien, gardez les SI imbriqués : SI.CONDITIONS n’y existe pas.

La famille de la fonction SI

Une fois SI maîtrisé, ces fonctions deviennent faciles :

  • SIERREUR remplace une erreur par la valeur de votre choix : =SIERREUR(B2/C2;0) affiche 0 au lieu de #DIV/0! quand C2 est vide.
  • NB.SI compte les cellules qui remplissent une condition : =NB.SI(C2:C50;"Admis") compte les admis.
  • SOMME.SI additionne selon une condition : =SOMME.SI(C2:C50;"Occitanie";B2:B50) additionne les ventes en Occitanie.
  • MOYENNE.SI fait la moyenne selon une condition, sur le même modèle.

Pour résumer tout un tableau d’un coup (le total par commercial, par mois ou par ville), sans écrire une formule par case, passez au tableau croisé dynamique.

Les erreurs les plus fréquentes

  • Le texte sans guillemets : =SI(B2>=18;Majeur;Mineur) donne #NOM?. Écrivez "Majeur".
  • Les guillemets courbes : copiée depuis Word ou un e-mail, une formule contient souvent des guillemets “typographiques” qu’Excel ne reconnaît pas. Retapez-les au clavier dans Excel.
  • La virgule au lieu du point-virgule : une formule copiée d’un site en anglais utilise des virgules. Dans un Excel en français, remplacez-les par des points-virgules.
  • Un nombre entre guillemets : B2>="18" compare un nombre à du texte, et le test est toujours faux. Écrivez B2>=18.
  • Des nombres stockés comme du texte : si un test sur des nombres échoue sans raison, vérifiez la cellule. Un petit triangle vert dans son coin signale souvent un nombre enregistré comme texte.
  • Une parenthèse oubliée : dans les SI imbriqués, comptez-les. Excel colore chaque paire de parenthèses pour vous aider.
  • Des conditions dans le mauvais ordre : avec des SI imbriqués ou SI.CONDITIONS, testez du plus exigeant au moins exigeant.

Questions fréquentes

Combien de SI peut-on imbriquer ? Jusqu’à 64. Mais au-delà de trois ou quatre, la formule devient illisible : passez à SI.CONDITIONS, ou à une table de correspondance avec RECHERCHEX (voir l’exemple de la grille de remises).

Que signifie l’erreur #NOM? dans une formule SI ? Le plus souvent, un texte n’est pas entre guillemets, ou le nom de la fonction est mal orthographié.

La fonction SI fonctionne-t-elle dans Google Sheets ? Oui, avec la même logique et les mêmes noms en français. Selon les paramètres régionaux du fichier, le séparateur est le point-virgule ou la virgule.

Comment écrire « si la cellule contient un mot » ? En combinant SI avec NB.SI et des jokers : =SI(NB.SI(A2;"*facture*");"Facture";"").

Vous voulez maîtriser SI et toutes les fonctions utiles au quotidien, sur vos propres fichiers ? C’est exactement ce qu’on fait en formation Excel, en petit groupe à Perpignan, jusqu’à la certification ICDL. Word est aussi au programme de nos formations bureautique à Perpignan.

Les raccourcis Excel

Le livret gratuit : 105 raccourcis sur Windows et sur Mac, à imprimer et à garder près de l’écran.

Recevoir le livret

Passer à la pratique

Une formation à Perpignan, en petit groupe, pour appliquer tout ça dans votre activité : parlons-en.

06 22 42 36 48contact@millorem.com